brainchime.com Latest Questions

Admin
Asked: 2024-10-13T06:59:25+05:30 In:

how to create ifs folder in as400?

How can we create an ifs folder (ifs directory) in a400? What do they store? Can we keep multiple folders (directories) inside an ifs folder (directory), or only store different files?

as400ifs

Related Questions

Leave an answer

Leave an answer

Browse
Browse

Choose from here the video type.

Put Video ID here: https://www.youtube.com/watch?v=sdUUx5FdySs Ex: "sdUUx5FdySs".

1 Answer

  1. Admin

    We can create an ifs folder using System I Navigator. Follow the below steps to create an ifs folder in the as400 machine.

    1. Open the System i Navigator.
    2. Click on the plus symbol (+) next to the Server (IP or domain).
    3. After node expansion, Click on the plus symbol (+) next to File Systems.
    4. After node expansion, Click on the plus symbol (+) next to Integrated File System.
    5. After node expansion, Click on Root.
    6. A dialog for creating a New folder appears, enter the new folder name in the respective field and click OK, leaving other fields as it is.

    The Ifs folder is the ifs directory. So, we can create an ifs directory from the server end. Use the mkdir (make directory) command to create an ifs folder(directory) in the AS400 system.

    Type MKDIR on the command line, then press F4. Enter your new folder name, including the complete path back to the root.

    mkdir () API can create a new or sub-directory in the IFS. mkdir() is make directory API. The prototypes in C and RPG language for mkdir() API are as follows:

    C prototype of mkdir():

    int mkdir(const char *path, mode_t mode)

    RPG prototype of mkdir() in fixed format:

         D mkdir           PR            10I 0 ExtProc('mkdir')               
     D  dirpath                        *   Value options(*string)         
     D  mode                         10U 0 Value

    RPG prototype of mkdir() in fully free format:

    DCL-PR mkdir int(10) EXTPROC('mkdir');       
  dirpath pointer VALUE options(string);    
  mode uns(10) VALUE;                        
END-PR;

    mkdir() accepts two parameters and returns an integer value.

    • Path parameter where we specify the folder/directory to be created.
    • The mode parameter is the access permissions assigned to the directory during creation.
    • mkdir() API returns -1 if the API call fails and 0 if it’s successful.

    Here is the RPG code in fixed format to create an ifs folder in as400.

         HDFTACTGRP(*NO)                                                      
     D mkdir           PR            10I 0 ExtProc('mkdir')               
     D  dirpath                        *   Value options(*string)         
     D  mode                         10U 0 Value                          
      *                                                                   
     D errorifs        PR              *   ExtProc('__errno')             
      *                                                                   
     D strerror        PR              *   ExtProc('strerror')            
     D error_num                     10I 0 value                          
      *                                                                   
     Dreturn_mkdir     s             10i 0 inz                            
     D dirpath         s            512a   inz                            
     D mode            s             10U 0 inz                            
                                                                          
     Derror_ptr        S               *                                  
     Derror_num        S             10I 0 based(error_ptr)               
                                                                          
     Derrormsg_ptr     S               *                                  
     Derror_msg        S             50a   based(errormsg_ptr)            
                                                                               
      *                                                         
      * owner,group,other (RWX)                                                
      *                                         owner authority                
     D M_readowner     C                   256                                 
     D M_writeowner    C                   128                                 
     D M_executeowner  C                   64                                  
      *                                         group authority                
     D M_readgroup     C                   32                                  
     D M_writegroup    C                   16                                  
     D M_executegroup  C                   8                                   
      *                                         other people                   
     D M_readother     C                   4                                   
     D M_writeother    C                   2                                   
     D M_executeother  C                   1                                   
      *                                                                        
     C                   EVAL      dirpath = '/home/developer/dir1'            
     C                   EVAL      mode = M_readowner +                        
     C                                    M_writeowner                         
     C                   EVAL      return_mkdir = mkdir(%trim(dirpath):mode)   
     C                   IF        return_mkdir < 0                   
     C                   EVAL      error_ptr = errorIFS()              
     C                   EVAL      errormsg_ptr = strerror(error_num)  
     C     error_msg     DSPLY                                         
     C                   RETURN                                        
     C                   ELSE                                          
     C     'DIR1 CREATED'DSPLY                                         
     C                   ENDIF

    Here is the RPG code in free format to create an ifs folder in as400.

         HDFTACTGRP(*NO)                                               
     D mkdir           PR            10I 0 ExtProc('mkdir')        
     D  dirpath                        *   Value options(*string)  
     D  mode                         10U 0 Value                   
      *                                                            
     D errorifs        PR              *   ExtProc('__errno')      
      *                                                            
     D strerror        PR              *   ExtProc('strerror')     
     D error_num                     10I 0 value                   
      *                                                            
     Dreturn_mkdir     s             10i 0 inz                     
     D dirpath         s            512a   inz                     
     D mode            s             10U 0 inz                     
                                                                   
     Derror_ptr        S               *                           
     Derror_num        S             10I 0 based(error_ptr)        
                                                                   
     Derrormsg_ptr     S               *                           
     Derror_msg        S             50a   based(errormsg_ptr)     
                                                                      
      * <-----mode---->                                               
      * owner,group,other (RWX)                                       
      *                                         owner authority       
     D M_readowner     C                   256                        
     D M_writeowner    C                   128                        
     D M_executeowner  C                   64                         
      *                                         group authority       
     D M_readgroup     C                   32                         
     D M_writegroup    C                   16                         
     D M_executegroup  C                   8                          
      *                                         other people          
     D M_readother     C                   4                          
     D M_writeother    C                   2                          
     D M_executeother  C                   1                          
      *                                                               
      /Free                                                           
       dirpath = '/home/developer/dir1';                              
       mode = M_readowner +                                           
              M_writeowner ;                                          
                                                     
       return_mkdir = mkdir(%trim(dirpath):mode);    
       if return_mkdir < 0;                         
         error_ptr = errorIFS();                     
         errormsg_ptr = strerror(error_num);         
         DSPLY error_msg;                            
         return;                                     
       else;                                         
         DSPLY 'DIR1 CREATED';                       
       endif;                                        
      /End-Free

    Here is the fully free RPG code to create an IFS folder in AS400.

    **FREE                                       
CTL-OPT DFTACTGRP(*NO);                      
                                             
DCL-PR errorifs pointer EXTPROC('__errno');  
END-PR;                                      
                                             
DCL-PR strerror pointer EXTPROC('strerror'); 
  error_num int(10) VALUE;                   
END-PR;                                      
                                             
DCL-PR mkdir int(10) EXTPROC('mkdir');       
  dirpath pointer VALUE options(*string);    
  mode uns(10) VALUE;                        
END-PR;                                      
                                             
DCL-S return_mkdir int(10) inz;              
DCL-S dirpath CHAR(512);                     
DCL-S mode  uns(10);                         
                                             
DCL-S error_ptr pointer;                                        
DCL-S error_num int(10) based(error_ptr);                       
DCL-S errormsg_ptr pointer;                                     
DCL-S error_msg char(50) based(errormsg_ptr);                   
                                                                
//    *                                         
//    * owner,group,other (RWX)                                 
//    *                                         owner authority 
DCL-C M_readowner 256;                                          
DCL-C M_writeowner 128;                                         
DCL-C M_executeowner 64;                                        
//    *                                         group authority 
DCL-C M_readgroup 32;                                           
DCL-C M_writegroup 16;                                          
DCL-C M_executegroup 8;                                         
//    *                                         other people    
DCL-C M_readother 4;                                            
DCL-C M_writeother 2;                                           
DCL-C M_executeother 1;                                         
                                                                
       dirpath = '/home/developer/dir1';          
       mode = M_readowner +                       
              M_writeowner ;                      
                                                  
       return_mkdir = mkdir(%trim(dirpath):mode); 
       if return_mkdir < 0;                      
         error_ptr = errorIFS();                  
         errormsg_ptr = strerror(error_num);      
         DSPLY error_msg;                         
         return;                                  
       else;                                      
         DSPLY 'DIR1 CREATED';                    
       endif; 
       return;